Привязка доменного имени к ВМ с веб-сервером с помощью Terraform

Статья создана

Yandex Cloud

Улучшена

kvendingoldo

Обновлена 4 декабря 2024 г.

Подготовьте облако к работе
- Необходимые платные ресурсы
Делегируйте домен сервису Cloud DNS
Создайте инфраструктуру
Проверьте работу сайта
Удалите созданные ресурсы

Чтобы создать инфраструктуру для привязки доменного имени к ВМ с веб-сервером с помощью Terraform:

Если созданные ресурсы вам больше не нужны, удалите их.

Подготовьте облако к работе

Зарегистрируйтесь в Yandex Cloud и создайте платежный аккаунт:

Перейдите в консоль управления, затем войдите в Yandex Cloud или зарегистрируйтесь.
На странице Yandex Cloud Billing убедитесь, что у вас подключен платежный аккаунт, и он находится в статусе ACTIVE или TRIAL_ACTIVE. Если платежного аккаунта нет, создайте его и привяжите к нему облако.

Если у вас есть активный платежный аккаунт, вы можете создать или выбрать каталог, в котором будет работать ваша инфраструктура, на странице облака.

Подробнее об облаках и каталогах.

Необходимые платные ресурсы

В стоимость поддержки создаваемого решения входят:

плата за использование публичного IP-адреса (см. тарифы Yandex Virtual Private Cloud);
плата за вычислительные ресурсы и диски ВМ (см. тарифы Yandex Compute Cloud);
плата за использование публичной DNS-зоны и публичные DNS-запросы (см. тарифы Yandex Cloud DNS).

Делегируйте домен сервису Cloud DNS

Чтобы делегировать домен сервису Cloud DNS, в личном кабинете вашего регистратора домена укажите в настройках домена адреса DNS-серверов:

ns1.yandexcloud.kz
ns2.yandexcloud.kz

Делегирование происходит не сразу. Серверы интернет-провайдеров обычно обновляют записи до 24 часов (86400 секунд). Это обусловлено значением TTL, в течение которого кэшируются записи для доменов.

Проверить делегирование домена можно с помощью сервиса Whois или утилиты dig:

dig +short NS example.com

Результат:

ns2.yandexcloud.kz.
ns1.yandexcloud.kz.

Terraform позволяет быстро создать облачную инфраструктуру в Yandex Cloud и управлять ею с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language). При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Terraform распространяется под лицензией Business Source License, а провайдер Yandex Cloud для Terraform — под лицензией MPL-2.0.

Подробную информацию о ресурсах провайдера смотрите в документации на сайте Terraform или в зеркале.

Для создания инфраструктуры c помощью Terraform:

Установите Terraform, получите данные для аутентификации и укажите источник для установки провайдера Yandex Cloud (раздел Настройте провайдер, шаг 1).

Подготовьте файл с описанием инфраструктуры:

Готовая конфигурация

Вручную

Клонируйте репозиторий с конфигурационными файлами.
```
git clone https://github.com/yandex-cloud-examples/yc-compute-dns-binding
```
Перейдите в директорию с репозиторием. В ней должны появиться файлы:
- bind-domain-to-vm.tf — конфигурация создаваемой инфраструктуры.
- bind-domain-to-vm.auto.tfvars — файл с пользовательскими данными.

Создайте папку для файла с описанием инфраструктуры.

Создайте в папке:

Конфигурационный файл bind-domain-to-vm.tf:

bind-domain-to-vm.tf

# Объявление переменных для пользовательских параметров

variable "folder_id" {
  type = string
}

variable "domain_name" {
  type = string
}

variable "ssh_key_path" {
  type = string
}

# Добавление прочих переменных

locals {
  zone             = "ru-central1-a"
  network_name     = "webserver-network"
  subnet_name      = "webserver-subnet-ru-central1-a"
  sg_name          = "webserver-sg"
  vm_name          = "mywebserver"
  domain_zone_name = "my-domain-zone"
}

# Настройка провайдера

terraform {
  required_providers {
    yandex = {
      source  = "yandex-cloud/yandex"
      version = ">= 0.47.0"
    }
  }
}

provider "yandex" {
  zone      = local.zone
  folder_id = var.folder_id
}

# Создание облачной сети

resource "yandex_vpc_network" "webserver-network" {
  name = local.network_name
}

# Создание подсети

resource "yandex_vpc_subnet" "webserver-subnet-b" {
  name           = local.subnet_name
  zone           = local.zone
  network_id     = "${yandex_vpc_network.webserver-network.id}"
  v4_cidr_blocks = ["192.168.1.0/24"]
}

# Создание группы безопасности

resource "yandex_vpc_security_group" "webserver-sg" {
  name        = local.sg_name
  network_id  = "${yandex_vpc_network.webserver-network.id}"
  ingress {
    protocol       = "TCP"
    description    = "http"
    v4_cidr_blocks = ["0.0.0.0/0"]
    port           = 80
  }

  ingress {
    protocol       = "TCP"
    description    = "https"
    v4_cidr_blocks = ["0.0.0.0/0"]
    port           = 443
  }

  ingress {
    protocol       = "TCP"
    description    = "ssh"
    v4_cidr_blocks = ["0.0.0.0/0"]
    port           = 22
  }

  egress {
    protocol       = "ANY"
    description    = "any"
    v4_cidr_blocks = ["0.0.0.0/0"]
    from_port      = 0
    to_port        = 65535
  }
}

# Создание образа

resource "yandex_compute_image" "osimage" {
  source_family = "lamp"
}

# Создание диска

resource "yandex_compute_disk" "boot-disk" {
  name     = "web-server-boot"
  type     = "network-hdd"
  image_id = yandex_compute_image.osimage.id
}

# Создание ВМ

resource "yandex_compute_instance" "mywebserver" {
  name        = local.vm_name
  platform_id = "standard-v2"
  zone        = local.zone

  resources {
    cores  = "2"
    memory = "2"
  }

  boot_disk {
    disk_id = yandex_compute_disk.boot-disk.id
  }

  network_interface {
    subnet_id          = "${yandex_vpc_subnet.webserver-subnet-b.id}"
    nat                = true
    security_group_ids = ["${yandex_vpc_security_group.webserver-sg.id}"]
  }

  metadata = {
    user-data = "#cloud-config\nusers:\n  - name: yc-user\n    groups: sudo\n    shell: /bin/bash\n    sudo: 'ALL=(ALL) NOPASSWD:ALL'\n    ssh_authorized_keys:\n      - ${file("${var.ssh_key_path}")}"
  }
}

# Создание зоны DNS

resource "yandex_dns_zone" "my-domain-zone" {
  name    = local.domain_zone_name
  zone    = "${var.domain_name}."
  public  = true
}

# Создание ресурсной записи типа А

resource "yandex_dns_recordset" "rsА1" {
  zone_id = yandex_dns_zone.my-domain-zone.id
  name    = "${yandex_dns_zone.my-domain-zone.zone}"
  type    = "A"
  ttl     = 600
  data    = ["${yandex_compute_instance.mywebserver.network_interface.0.nat_ip_address}"]
}

Файл с пользовательскими данными bind-domain-to-vm.auto.tfvars:

bind-domain-to-vm.auto.tfvars

folder_id    = "<идентификатор_каталога>"
ssh_key_path = "<путь_к_SSH-ключу>"
domain_name  = "<имя_домена>"

Более подробную информацию о параметрах используемых ресурсов в Terraform см. в документации провайдера:

Сеть — yandex_vpc_network
Подсети — yandex_vpc_subnet
Группы безопасности — yandex_vpc_security_group
Образ — yandex_compute_image
Диск — yandex_compute_disk
ВМ — yandex_compute_instance
DNS-зона — yandex_dns_zone
Ресурсная запись DNS — yandex_dns_recordset

В файле bind-domain-to-vm.auto.tfvars задайте пользовательские параметры:
- folder_id — идентификатор каталога.
- ssh_key_path — путь к файлу с открытым SSH-ключом для аутентификации пользователя на ВМ, например ~/.ssh/id_ed25519.pub. Подробнее см. Создание пары ключей SSH.
- domain_name — имя вашего домена, например example.com.
Создайте ресурсы:
1. В терминале перейдите в папку, где вы отредактировали конфигурационный файл.
2. Проверьте корректность конфигурационного файла с помощью команды:
```
terraform validate
```
  Если конфигурация является корректной, появится сообщение:
```
Success! The configuration is valid.
```
3. Выполните команду:
```
terraform plan
```
  В терминале будет выведен список ресурсов с параметрами. На этом этапе изменения не будут внесены. Если в конфигурации есть ошибки, Terraform на них укажет.
4. Примените изменения конфигурации:
```
terraform apply
```
5. Подтвердите изменения: введите в терминале слово yes и нажмите Enter.
Получите публичный IP-адрес ВМ — он потребуется далее, чтобы проверить работу хостинга.

После создания инфраструктуры, проверьте работу сайта.

Проверьте работу сайта

Теперь сайт на вашем веб-сервере доступен по доменному имени. Чтобы проверить работу сайта, введите в браузере его IP-адрес или доменное имя:

http://<публичный_IP-адрес_ВМ>
http://example.com

Удалите созданные ресурсы

Чтобы остановить работу хостинга и перестать платить за созданные ресурсы:

Откройте конфигурационный файл bind-domain-to-vm.tf и удалите описание создаваемой инфраструктуры из файла.
Примените изменения:
1. В терминале перейдите в папку, где вы отредактировали конфигурационный файл.
2. Проверьте корректность конфигурационного файла с помощью команды:
```
terraform validate
```
  Если конфигурация является корректной, появится сообщение:
```
Success! The configuration is valid.
```
3. Выполните команду:
```
terraform plan
```
  В терминале будет выведен список ресурсов с параметрами. На этом этапе изменения не будут внесены. Если в конфигурации есть ошибки, Terraform на них укажет.
4. Примените изменения конфигурации:
```
terraform apply
```
5. Подтвердите изменения: введите в терминале слово yes и нажмите Enter.

См. также

Привязка доменного имени к ВМ с веб-сервером с помощью консоли управления, CLI или API.

Привязка доменного имени к ВМ с веб-сервером с помощью Terraform

Подготовьте облако к работеПодготовьте облако к работе

Необходимые платные ресурсыНеобходимые платные ресурсы

Делегируйте домен сервису Cloud DNSДелегируйте домен сервису Cloud DNS

Создайте инфраструктуруСоздайте инфраструктуру

Проверьте работу сайтаПроверьте работу сайта

Удалите созданные ресурсыУдалите созданные ресурсы

См. такжеСм. также

Была ли статья полезна?