Отказоустойчивый сайт с балансировкой нагрузки через Yandex Network Load Balancer с помощью Terraform

Статья создана

Yandex Cloud

Улучшена

Обновлена 30 октября 2024 г.

Подготовьте облако к работе
- Необходимые платные ресурсы
Создайте инфраструктуру
Загрузите файлы веб-сайта
Протестируйте отказоустойчивость
Как удалить созданные ресурсы

Чтобы создать отказоустойчивый сайт с балансировкой нагрузки через Yandex Network Load Balancer с помощью Terraform:

Если созданные ресурсы вам больше не нужны, удалите их.

Подготовьте облако к работе

Зарегистрируйтесь в Yandex Cloud и создайте платежный аккаунт:

Перейдите в консоль управления, затем войдите в Yandex Cloud или зарегистрируйтесь.
На странице Yandex Cloud Billing убедитесь, что у вас подключен платежный аккаунт, и он находится в статусе ACTIVE или TRIAL_ACTIVE. Если платежного аккаунта нет, создайте его и привяжите к нему облако.

Если у вас есть активный платежный аккаунт, вы можете создать или выбрать каталог, в котором будет работать ваша инфраструктура, на странице облака.

Подробнее об облаках и каталогах.

Необходимые платные ресурсы

В стоимость поддержки веб-сайта входит:

плата за диски и постоянно запущенные ВМ (см. тарифы Yandex Compute Cloud);
плата за использование динамичесих или статических внешних IP-адресов (см. тарифы Yandex Virtual Private Cloud);
плата за сетевой балансировщик и балансировку трафика (см. тарифы Network Load Balancer).

Terraform позволяет быстро создать облачную инфраструктуру в Yandex Cloud и управлять ею с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language). При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Terraform распространяется под лицензией Business Source License, а провайдер Yandex Cloud для Terraform — под лицензией MPL-2.0.

Подробную информацию о ресурсах провайдера смотрите в документации на сайте Terraform или в зеркале.

Для создания инфраструктуры c помощью Terraform:

Установите Terraform, получите данные для аутентификации и укажите источник для установки провайдера Yandex Cloud (раздел Настройте провайдер, шаг 1).

Подготовьте файлы с описанием инфраструктуры:

Готовая конфигурация

Вручную

Склонируйте репозиторий с конфигурационными файлами:
```
git clone https://github.com/yandex-cloud-examples/yc-nlb-fault-tolerant-site.git
```
Перейдите в директорию с репозиторием. В ней должен появиться файл load-balancer.tf с конфигурацией создаваемой инфраструктуры.

Создайте папку для файлов.

Создайте в папке конфигурационный файл load-balancer.tf:

load-balancer.tf

terraform {
  required_providers {
    yandex = {
      source  = "yandex-cloud/yandex"
      version = ">= 0.47.0"
    }
  }
}

provider "yandex" {
  zone = "ru-central1-a"
}

variable "folder_id" {
  description = "Yandex.Cloud Folder ID where resources will be created"
  default     = "<идентификатор_каталога>"
}

resource "yandex_iam_service_account" "ig-sa" {
  name        = "ig-sa"
}

resource "yandex_resourcemanager_folder_iam_member" "editor" {
  folder_id = var.folder_id
  role      = "editor"
  member    = "serviceAccount:${yandex_iam_service_account.ig-sa.id}"
}

resource "yandex_compute_instance_group" "ig-1" {
  name               = "nlb-vm-group"
  folder_id          = var.folder_id
  service_account_id = "${yandex_iam_service_account.ig-sa.id}"
  instance_template {
    platform_id = "standard-v3"
    resources {
      core_fraction = 20
      memory        = 1
      cores         = 2
    }

    boot_disk {
      mode = "READ_WRITE"
      initialize_params {
        image_id = "<идентификатор_образа>"
        type     = "network-hdd"
        size     = 3
      }
    }

    network_interface {
      network_id = "${yandex_vpc_network.network-1.id}"
      subnet_ids = ["${yandex_vpc_subnet.subnet-1.id}","${yandex_vpc_subnet.subnet-2.id}" ]
      nat        = true
    }

    metadata = {
      user-data = "#cloud-config\nusers:\n  - name: <имя_пользователя>\n    groups: sudo\n    shell: /bin/bash\n    sudo: 'ALL=(ALL) NOPASSWD:ALL'\n    ssh_authorized_keys:\n      - ${file("<путь_к_открытому_SSH-ключу>")}"
    }
  }

  scale_policy {
    fixed_scale {
      size = 2
    }
  }

  allocation_policy {
    zones = ["ru-central1-a", "ru-central1-b"]
  }

  deploy_policy {
    max_unavailable = 1
    max_expansion   = 0
  }

  load_balancer {
    target_group_name = "nlb-tg"
  }
}

resource "yandex_lb_network_load_balancer" "foo" {
  name = "nlb-1"
  listener {
    name = "nlb-listener"
    port = 80
  }
  attached_target_group {
    target_group_id = "${yandex_compute_instance_group.ig-1.load_balancer.0.target_group_id}"
    healthcheck {
      name                = "health-check-1"
      unhealthy_threshold = 5
      healthy_threshold   = 5
      http_options {
        port = 80
      }
    }
  }
}

resource "yandex_vpc_network" "network-1" {
  name = "network1"
}

resource "yandex_vpc_subnet" "subnet-1" {
  name           = "subnet1"
  zone           = "ru-central1-a"
  network_id     = "${yandex_vpc_network.network-1.id}"
  v4_cidr_blocks = ["192.168.1.0/24"]
}

resource "yandex_vpc_subnet" "subnet-2" {
  name           = "subnet2"
  zone           = "ru-central1-b"
  network_id     = "${yandex_vpc_network.network-1.id}"
  v4_cidr_blocks = ["192.168.2.0/24"]
}

Более подробную информацию о параметрах используемых ресурсов в Terraform см. в документации провайдера:

В блоке variable укажите значение переменной folder_id — идентификатор каталога, в котором создаются необходимые ресурсы.
В блоке metadata укажите метаданные для создания ВМ и содержимое SSH-ключа. Ключ указывается в формате <любое_имя>:<содержимое_SSH-ключа>. Указанное имя пользователя не играет роли, ключ будет присвоен пользователю, который задан в конфигурации образа LAMP (LEMP). В разных образах это разные пользователи. Подробнее см. в разделе Ключи, обрабатываемые в публичных образах.

Пару SSH-ключей необходимо создать самостоятельно.
В блоке boot_disk укажите идентификатор одного из образов ВМ с нужным набором компонентов:
- LAMP (Linux, Apache, MySQL®, PHP).
- LEMP (Linux, Nginx, MySQL®, PHP).
Создайте ресурсы:
1. В терминале перейдите в папку, где вы отредактировали конфигурационный файл.
2. Проверьте корректность конфигурационного файла с помощью команды:
```
terraform validate
```
  Если конфигурация является корректной, появится сообщение:
```
Success! The configuration is valid.
```
3. Выполните команду:
```
terraform plan
```
  В терминале будет выведен список ресурсов с параметрами. На этом этапе изменения не будут внесены. Если в конфигурации есть ошибки, Terraform на них укажет.
4. Примените изменения конфигурации:
```
terraform apply
```
5. Подтвердите изменения: введите в терминале слово yes и нажмите Enter.

После создания инфраструктуры, загрузите файлы веб-сайта.

Загрузите файлы веб-сайта

Чтобы проверить работу веб-сервера, необходимо загрузить файлы сайта на каждую ВМ. Для примера вы можете использовать файл index.html из архива.

Для каждой ВМ в созданной группе выполните следующее:

Узнайте публичный IP-адрес нужной ВМ.
Подключитесь к ВМ по протоколу SSH.
Выдайте права на запись для вашего пользователя на директорию /var/www/html:
```
sudo chown -R "$USER":www-data /var/www/html
```
Загрузите на ВМ файлы веб-сайта с помощью протокола SCP.
Linux/macOS

Windows
Используйте утилиту командной строки scp:
```
scp -r <путь_до_директории_с_файлами> <имя_пользователя_ВМ>@<IP-адрес_ВМ>:/var/www/html
```
С помощью программы WinSCP скопируйте локальную директорию с файлами в директорию /var/www/html на ВМ.

После загрузки всех файлов, протестируйте отказоустойчивость.

Протестируйте отказоустойчивость

Узнайте публичный IP-адрес любой ВМ из созданной группы.
Подключитесь к ВМ по протоколу SSH.
Остановите веб-сервис, чтобы сымитировать сбой в работе веб-сервера:
LAMP

LEMP
```
sudo service apache2 stop
```
```
sudo service nginx stop
```
Узнайте IP-адрес обработчика.
Откройте сайт в браузере, используя адрес обработчика.

Несмотря на сбой в работе одного из веб-серверов, подключение должно пройти успешно.
После завершения проверки снова запустите веб-сервис:
LAMP

LEMP
```
sudo service apache2 start
```
```
sudo service nginx start
```

Как удалить созданные ресурсы

Чтобы остановить работу веб-сайта и перестать платить за созданные ресурсы:

Откройте конфигурационный файл load-balancer.tf и удалите описание создаваемой инфраструктуры из файла.
Примените изменения:
1. В терминале перейдите в папку, где вы отредактировали конфигурационный файл.
2. Проверьте корректность конфигурационного файла с помощью команды:
```
terraform validate
```
  Если конфигурация является корректной, появится сообщение:
```
Success! The configuration is valid.
```
3. Выполните команду:
```
terraform plan
```
  В терминале будет выведен список ресурсов с параметрами. На этом этапе изменения не будут внесены. Если в конфигурации есть ошибки, Terraform на них укажет.
4. Примените изменения конфигурации:
```
terraform apply
```
5. Подтвердите изменения: введите в терминале слово yes и нажмите Enter.

См. также

Отказоустойчивый сайт с балансировкой нагрузки через Yandex Network Load Balancer с помощью консоли управления

Отказоустойчивый сайт с балансировкой нагрузки через Yandex Network Load Balancer с помощью Terraform

Подготовьте облако к работеПодготовьте облако к работе

Необходимые платные ресурсыНеобходимые платные ресурсы

Создайте инфраструктуруСоздайте инфраструктуру

Загрузите файлы веб-сайтаЗагрузите файлы веб-сайта

Протестируйте отказоустойчивостьПротестируйте отказоустойчивость

Как удалить созданные ресурсыКак удалить созданные ресурсы

См. такжеСм. также

Была ли статья полезна?