Настроить наборы правил WAF

Terraform позволяет быстро создать облачную инфраструктуру в Yandex Cloud и управлять ею с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language). При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Terraform распространяется под лицензией Business Source License, а провайдер Yandex Cloud для Terraform — под лицензией MPL-2.0.

Подробная информация о ресурсах провайдера в документации на сайте Terraform или в зеркале.

Если у вас еще нет Terraform, установите его и настройте провайдер Yandex Cloud.

Чтобы управлять инфраструктурой с помощью Terraform от имени сервисного аккаунта или пользовательских аккаунтов: аккаунта на Яндексе, федеративного аккаунта и локального пользователя, аутентифицируйтесь соответствующим способом.

Вы можете динамически включить все правила из базового набора, если их уровень паранойи не выше значения пользовательской переменной. Для правил, которые настроены динамически, можно вручную изменить параметры. Например, сделать правило блокирующим и сделать активным правило, у которого уровень паранойи выше, чем задан в переменной.

1. Откройте файл конфигурации Terraform и измените фрагмент с описанием профиля WAF yandex_sws_waf_profile: добавьте блок rule с правилом безопасности или блок dynamic "rule" с правилами, которые настраиваются динамически.

   # Объявление локальных переменных
   locals {
     # В базовом наборе будут активны правила этого уровня паранойи и ниже
     waf_paranoia_level = <уровень_паранойи>
   }
   
   # Источник данных — набор правил
   data "yandex_sws_waf_rule_set_descriptor" "source" {
     name    = "<имя_набора>"
   }
   
   # Профиль WAF
   resource "yandex_sws_waf_profile" "default" {
     name = "default"
   
     ...
   
     # Назначаем правило блокирующим — запрос будет заблокирован независимо от порога аномальности
     rule {
       rule_id     = "<идентификатор_правила_1>"
       is_enabled  = true
       is_blocking = true
     }
   
     # Назначаем активным правило с уровнем паранойи 4
     rule {
       rule_id     = "<идентификатор_правила_2>"
       is_enabled  = true
       is_blocking = false
     }
   
     # Активируем правила из базового набора, если их уровень паранойи не выше заданного в переменной waf_paranoia_level
     dynamic "rule" {
       for_each = [
         for rule in data.yandex_sws_waf_rule_set_descriptor.source.rules : rule
         if rule.paranoia_level <= local.waf_paranoia_level
       ]
       content {
         rule_id     = rule.value.id
         is_enabled  = true
         is_blocking = false
       }
     }
   }
   
   Пример настройки наборов правил профиля WAF в конфигурации Terraform

   # Объявление локальных переменных
   locals {
     # В базовом наборе будут активны правила этого уровня паранойи и ниже
     waf_paranoia_level = 1
   
     # Идентификация набора правил OWASP Core Ruleset
     ruleset_name    = "OWASP Core Ruleset"
     ruleset_version = "4.0.0"
     ruleset_id      = "OWASP_CRS_4_0_0"
     ruleset_type    = "CORE"
   }
   
   # Источник данных OWASP Core Rule Set
   data "yandex_sws_waf_rule_set_descriptor" "source" {
     name    = local.ruleset_name
     version = local.ruleset_version
   }
   
   # Профиль WAF
   resource "yandex_sws_waf_profile" "default" {
     name = "default"
   
     # Базовый набор правил
     rule_set {
       action     = "DENY"
       is_enabled = true
       priority   = 1
       core_rule_set {
         inbound_anomaly_score = 2
         paranoia_level        = local.waf_paranoia_level
         rule_set {
           name    = local.ruleset_name
           version = local.ruleset_version
           id      = local.ruleset_id
           type    = local.ruleset_type
         }
       }
     }
   
     # Назначаем правило блокирующим — запрос будет заблокирован независимо от порога аномальности
     rule {
       rule_id     = "owasp-crs-v4.0.0-id942330-attack-sqli"
       is_enabled  = true
       is_blocking = true
     }
   
     # Назначаем активным правило с уровнем паранойи 4
     rule {
       rule_id     = "owasp-crs-v4.0.0-id920202-protocol-enforcement"
       is_enabled  = true
       is_blocking = false
     }
   
     # Активируем правила из базового набора, если их уровень паранойи не выше заданного в переменной waf_paranoia_level
     dynamic "rule" {
       for_each = [
         for rule in data.yandex_sws_waf_rule_set_descriptor.source.rules : rule
         if rule.paranoia_level <= local.waf_paranoia_level
       ]
       content {
         rule_id     = rule.value.id
         is_enabled  = true
         is_blocking = false
       }
     }
   }
   

   Где:

   • rule — описание правила безопасности:

     • rule_id — идентификатор правила.
     • is_enabled — флаг включения или отключения правила.
     • is_blocking — флаг блокировки правила. Если значение true, правило становится блокирующим.

   • dynamic "rule" — динамическая активация правил из базового набора, если их уровень паранойи не выше значения переменной waf_paranoia_level. Для правил, которые настроены динамически, можно вручную изменить параметры. Например, сделать правило блокирующим или сделать активным правило, у которого уровень паранойи выше, чем указан в переменной.

     • rule_id — идентификатор правила.
     • is_enabled — флаг включения или отключения правила.
     • is_blocking — флаг блокировки правила. Если значение true, правило становится блокирующим.

   Подробнее о параметрах ресурса yandex_sws_waf_profile в документации провайдера.

2. Примените изменения:

   1. В терминале перейдите в директорию с конфигурационным файлом.

   2. Проверьте корректность конфигурации с помощью команды:

      terraform validate
      

      Если конфигурация является корректной, появится сообщение:

      Success! The configuration is valid.
      

   3. Выполните команду:

      terraform plan
      

      В терминале будет выведен список ресурсов с параметрами. На этом этапе изменения не будут внесены. Если в конфигурации есть ошибки, Terraform на них укажет.

   4. Примените изменения конфигурации:

      terraform apply
      

   5. Подтвердите изменения: введите в терминале слово yes и нажмите Enter.

Вы можете проверить изменение ресурсов в консоли управления.

Воспользуйтесь методом REST API update для ресурса WafProfile или вызовом gRPC API WafProfile/Update.