Creating a MongoDB cluster

If you do not have the Yandex Cloud CLI yet, install and initialize it.

The folder specified when creating the CLI profile is used by default. To change the default folder, use the yc config set folder-id <folder_ID> command. You can specify a different folder using the --folder-name or --folder-id parameter.

To create a Managed Service for MongoDB cluster:

1. Check whether the folder has any subnets for the cluster hosts:

   yc vpc subnet list
   

   If there are no subnets in the folder, create the required subnets in VPC.

2. View the description of the CLI command to create a cluster:

   yc managed-mongodb cluster create --help
   

3. Specify the cluster parameters in the create command (not all parameters are given in the example):

   yc managed-mongodb cluster create \
     --name <cluster_name> \
     --environment=<environment> \
     --network-name <network_name> \
     --host zone-id=<availability_zone>,`
           `subnet-id=<subnet_ID>,`
           `assign-public-ip=<public_access_to_host>,`
           `hidden=<hide_host>,`
           `secondary-delay-secs=<replica_lag_in_seconds>,`
           `priority=<host_priority> \
     --mongod-resource-preset <host_class> \
     --user name=<username>,password=<user_password> \
     --database name=<DB_name> \
     --mongod-disk-type <network-hdd|network-ssd|network-ssd-nonreplicated|local-ssd> \
     --mongod-disk-size <storage_size_in_GB> \
     --performance-diagnostics=<enable_diagnostics> \
     --deletion-protection
   

   You need to specify the subnet-id if the selected availability zone has two or more subnets.

   Where:

   • --environment: Environment, prestable or production.

   • --host: Host parameters:

     • zone-id: Availability zone.
     • subnet-id: Subnet ID. Specify if two or more subnets are created in the selected availability zone.
     • assign-public-ip: Internet access to the host via a public IP address, true or false.
     • hidden: Hide host, true or false. If the host is hidden, only direct connections will be able to read from it (for example, to make backups from it without adding load to the cluster).
     • secondary-delay-secs: Replica's lag behind the master in seconds. It can be useful for data recovery in case of invalid operations.
     • priority: Priority for assigning the host as a master.

   • --mongod-disk-type: Disk type.

   • --performance-diagnostics: Enables cluster performance diagnostics, true or false.

   • --deletion-protection: Cluster protection from accidental deletion, true or false.

     Even with cluster deletion protection enabled, one can still delete a user or database or connect manually and delete the database contents.

   A database name may contain Latin letters, numbers, underscores, and hyphens. The name may be up to 63 characters long. Such names as config, local, admin, and mdb_internal are reserved for Managed Service for MongoDB. You cannot create DBs with these names.

   Note

   When creating a cluster, the anytime maintenance mode is set by default. You can set a specific maintenance period when updating the cluster settings.

With Terraform, you can quickly create a cloud infrastructure in Yandex Cloud and manage it using configuration files. These files store the infrastructure description written in HashiCorp Configuration Language (HCL). If you change the configuration files, Terraform automatically detects which part of your configuration is already deployed, and what should be added or removed.

Terraform is distributed under the Business Source License. The Yandex Cloud provider for Terraform is distributed under the MPL-2.0 license.

For more information about the provider resources, see the documentation on the Terraform website or mirror website.

If you do not have Terraform yet, install it and configure its Yandex Cloud provider.

To create a Managed Service for MongoDB cluster:

1. In the configuration file, describe the resources you want to create:

   • Database cluster: Description of the cluster and its hosts.

   • Network: Description of the cloud network where a cluster will be located. If you already have a suitable network, you don't have to describe it again.

   • Subnets: Description of the subnets to connect the cluster hosts to. If you already have suitable subnets, you don't have to describe them again.

   Here is an example of the configuration file structure:

   resource "yandex_mdb_mongodb_cluster" "<cluster_name>" {
     name                = "<cluster_name>"
     environment         = "<environment>"
     network_id          = "<network_ID>"
     security_group_ids  = [ "<list_of_security_group_IDs>" ]
     deletion_protection = <cluster_deletion_protection>
   
     cluster_config {
       version = "<MongoDB_version>"
     }
   
     resources_mongod {
       resource_preset_id = "<host_class>"
       disk_type_id       = "<disk_type>"
       disk_size          = <storage_size_in_GB>
     }
   
     host {
       zone_id          = "<availability_zone>"
       subnet_id        = "<subnet_ID>"
       assign_public_ip = <public_access>
       host_parameters {
         hidden               = <hide_host>
         secondary_delay_secs = <replica_lag_in_seconds>
         priority             = <host_priority>
       }
     }
   }
   
   resource "yandex_mdb_mongodb_database" "<DB_name>" {
     cluster_id = "<cluster_ID>"
     name       = "<DB_name>"
   }
   
   resource "yandex_mdb_mongodb_user" "<username>" {
     cluster_id = <cluster_ID>
     name       = "<username>"
     password   = "<password>"
     permission {
       database_name = "<DB_name>"
       roles         = [ "<list_of_user_roles>" ]
     }
     depends_on = [
       yandex_mdb_mongodb_database.<DB_name>
     ]
   }
   
   resource "yandex_vpc_network" "<network_name>" { name = "<network_name>" }
   
   resource "yandex_vpc_subnet" "<subnet_name>" {
     name           = "<subnet_name>"
     zone           = "<availability_zone>"
     network_id     = "<network_ID>"
     v4_cidr_blocks = ["<range>"]
   }
   

   Where:

   • environment: Environment, PRESTABLE or PRODUCTION.

   • host: Host parameters:

     • zone_id: Availability zone.
     • subnet_id: ID of a subnet in the selected availability zone.
     • assign_public_ip: Public access to the host, true or false.
     • host_parameters: Additional host parameters:
       • hidden: Hide host, true or false. If the host is hidden, only direct connections will be able to read from it (for example, to make backups from it without adding load to the cluster).
       • secondary_delay_secs: Replica's lag behind the master in seconds. It can be useful for data recovery in case of invalid operations.
       • priority: Host priority for assignment as a master.

   • deletion_protection: Cluster protection from accidental deletion, true or false.

     Even with cluster deletion protection enabled, one can still delete a user or database or connect manually and delete the database contents.

   • version: MongoDB version, 6.0 or 7.0.

   A database name may contain Latin letters, numbers, underscores, and hyphens. The name may be up to 63 characters long. Such names as config, local, admin, and mdb_internal are reserved for Managed Service for MongoDB. You cannot create DBs with these names.

   To set up the maintenance window (for disabled clusters as well), add the maintenance_window block to the cluster description:

   resource "yandex_mdb_mongodb_cluster" "<cluster_name>" {
     ...
     maintenance_window {
       type = <maintenance_type>
       day  = <day_of_week>
       hour = <hour>
     }
     ...
   }
   

   Where:

   • type: Maintenance type. The possible values include:
     • anytime: Anytime.
     • weekly: By schedule.
   • day: Day of the week for the weekly type in DDD format, e.g., MON.
   • hour: Hour of the day for the weekly type in the HH format, e.g., 21.

   For more information about the resources you can create with Terraform, see this provider reference.

2. Make sure the settings are correct.

   1. In the command line, navigate to the directory that contains the current Terraform configuration files defining the infrastructure.

   2. Run this command:

      terraform validate
      

      Terraform will show any errors found in your configuration files.

3. Create a cluster.

   1. Run this command to view the planned changes:

      terraform plan
      

      If you described the configuration correctly, the terminal will display a list of the resources to update and their parameters. This is a verification step that does not apply changes to your resources.

   2. If everything looks correct, apply the changes:

      1. Run this command:

         terraform apply
         

      2. Confirm updating the resources.

      3. Wait for the operation to complete.

   After this, all required resources will be created in the specified folder, and the host FQDNs will be displayed in the terminal. You can check the new resources and their settings using the management console.

   Timeouts

   The Terraform provider sets the following timeouts for Managed Service for MongoDB cluster operations:

   • Creating a cluster, including by restoring one from a backup: 30 minutes.
   • Editing a cluster: 60 minutes.

   Operations exceeding the set timeout are interrupted.

   How do I change these limits?

   Add the timeouts block to the cluster description, for example:

   resource "yandex_mdb_mongodb_cluster" "<cluster_name>" {
     ...
     timeouts {
       create = "1h30m" # An hour and a half
       update = "2h"    # Two hours
     }
   }
   

1. Get an IAM token for API authentication and put it into the environment variable:

   export IAM_TOKEN="<IAM_token>"
   

2. Create a file named body.json and add the following contents to it:

   {
     "folderId": "<folder_ID>",
     "name": "<cluster_name>",
     "environment": "<environment>",
     "networkId": "<network_ID>",
     "securityGroupIds": [
       "<security_group_1_ID>",
       "<security_group_2_ID>",
       ...
       "<security_group_N_ID>"
     ],
     "deletionProtection": <cluster_deletion_protection:_true_or_false>,
     "maintenanceWindow": {
       "weeklyMaintenanceWindow": {
         "day": "<day_of_week>",
         "hour": "<hour>"
       }
     },
     "configSpec": {
       "version": "<MongoDB_version>",
       "mongodb": {
         "mongod": {
           "resources": {
             "resourcePresetId": "<host_class>",
             "diskSize": "<storage_size_in_bytes>",
             "diskTypeId": "<disk_type>"
           }
         }
       },
       "backupWindowStart":  {
         "hours": "<hours>",
         "minutes": "<minutes>",
         "seconds": "<seconds>",
         "nanos": "<nanoseconds>"
       },  
       "backupRetainPeriodDays": "<backup_retention_in_days>",
       "performanceDiagnostics": {
         "profilingEnabled": <enable_profiler:_true_or_false>
       }
     },
     "databaseSpecs": [
       {
         "name": "<DB_name>"
       },
       { <similar_configuration_for_DB_2> },
       { ... },
       { <similar_configuration_for_DB_N> }
     ],
     "userSpecs": [
       {
         "name": "<username>",
         "password": "<user_password>",
         "permissions": [
           {
             "databaseName": "<DB_name>",
             "roles": [
               "<role_1>", "<role_2>", ..., "<role_N>"
             ]
           }
         ]
       },
       { <similar_configuration_for_user_2> },
       { ... },
       { <similar_configuration_for_user_N> }
     ],
     "hostSpecs": [
       {
         "zoneId": "<availability_zone>",
         "subnetId": "<subnet_ID>",
         "assignPublicIp": <public_access_to_host:_true_or_false>,
         "type": "<host_type>",
         "shardName": "<shard_name>",
         "hidden": <hide_host:_true_or_false>,
         "secondaryDelaySecs": "<replica_lag_in_seconds>",
         "priority": "<host_priority>",
         "tags": "<host_labels>"
       },
       { <similar_configuration_for_host_2> },
       { ... },
       { <similar_configuration_for_host_N> }
     ],
   }
   

   Where:

   • folderId: Folder ID. You can request it with the list of folders in the cloud.

   • name: Cluster name.

   • environment: Cluster environment, PRODUCTION or PRESTABLE.

   • networkId: ID of the network the cluster will be in.

   • securityGroupIds: Security group IDs.

   • deletionProtection: Cluster protection from accidental deletion, true or false.

     Even with cluster deletion protection enabled, one can still delete a user or database or connect manually and delete the database contents.

   • maintenanceWindow: Maintenance window settings (including for disabled clusters). In maintenanceWindow, provide one of the two parameters:

     • anytime: Maintenance can take place at any time.

     • weeklyMaintenanceWindow: Maintenance takes place once a week at the specified time:

       • day: Day of week, in DDD format.
       • hour: Hour, in HH format. The values range from 1 to 24 hours.

   • configSpec: Cluster settings:

     • version: MongoDB version: 5.0, 6.0, or 7.0.

     • mongod: Host type.

       • resources: Cluster resources:

         • resourcePresetId: Host class.
         • diskSize: Disk size in bytes.
         • diskTypeId: Disk type.

     • backupWindowStart: Backup window settings.

       In this parameter, specify the backup start time:

       • hours: Between 0 and 23 hours.
       • minutes: Between 0 and 59 minutes.
       • seconds: Between 0 and 59 seconds.
       • nanos: Between 0 and 999999999 nanoseconds.

     • backupRetainPeriodDays: Backup retention in days.

     • performanceDiagnostics: Statistics collection settings:

       • profilingEnabled: Enable profiler.

   • databaseSpecs: Database settings as an array of elements, one for each DB. Each element contains the name parameter with the DB name.

     A database name may contain Latin letters, numbers, underscores, and hyphens. The name may be up to 63 characters long. Such names as config, local, admin, and mdb_internal are reserved for Managed Service for MongoDB. You cannot create DBs with these names.

   • userSpecs: User settings as an array of elements, one for each user. Each element has the following structure:

     • name: Username.

     • password: User password.

     • permissions: User permissions settings:

       • databaseName: Name of the database the user gets access to.
       • roles: Array of user roles. Each role is provided as a separate string in the array. For a list of possible values, see Users and roles.

       For each database, add a separate element with permission settings to the permissions array.

   • hostSpecs: Cluster host settings as an array of elements, one for each host. Each element has the following structure:

     • zoneId: Availability zone.
     • subnetId: Subnet ID.
     • assignPublicIp: Internet access to the host via a public IP address.
     • type: Host type in a sharded cluster, MONGOD, MONGOINFRA, MONGOS, or MONGOCFG.
     • shardName: Shard name in a sharded cluster.
     • hidden: Hide host, true or false. If the host is hidden, only direct connections will be able to read from it (for example, to make backups from it without adding load to the cluster).
     • secondaryDelaySecs: Replica's lag behind the master in seconds. It can be useful for data recovery in case of invalid operations.
     • priority: Host priority for assignment as a master.
     • tags: Host labels.

3. Use the Cluster.Create method and send the following request, e.g., via cURL:

   curl \
       --request POST \
       --header "Authorization: Bearer $IAM_TOKEN" \
       --header "Content-Type: application/json" \
       --url 'https://mdb.api.cloud.yandex.net/managed-mongodb/v1/clusters' \
       --data "@body.json"
   

4. View the server response to make sure the request was successful.

1. Get an IAM token for API authentication and put it into the environment variable:

   export IAM_TOKEN="<IAM_token>"
   

2. Clone the cloudapi repository:

   cd ~/ && git clone --depth=1 https://github.com/yandex-cloud/cloudapi
   

   Below, we assume the repository contents are stored in the ~/cloudapi/ directory.

3. Create a file named body.json and add the following contents to it:

   {
     "folder_id": "<folder_ID>",
     "name": "<cluster_name>",
     "environment": "<environment>",
     "network_id": "<network_ID>",
     "security_group_ids": [
       "<security_group_1_ID>",
       "<security_group_2_ID>",
       ...
       "<security_group_N_ID>"
     ],
     "deletion_protection": <cluster_deletion_protection:_true_or_false>,
     "maintenance_window": {
       "weekly_maintenance_window": {
         "day": "<day_of_week>",
         "hour": "<hour>"
       }
     },
     "config_spec": {
       "version": "<MongoDB_version>",
       "mongodb": {
         "mongod": {
           "resources": {
             "resource_preset_id": "<host_class>",
             "disk_size": "<storage_size_in_bytes>",
             "disk_type_id": "<disk_type>"
           }
         }
       },
       "backup_window_start": {
         "hours": "<hours>",
         "minutes": "<minutes>",
         "seconds": "<seconds>",
         "nanos": "<nanoseconds>"
       },
       "backup_retain_period_days": "<backup_retention_in_days>",
       "performance_diagnostics": {
         "profiling_enabled": <enable_profiler:_true_or_false>
       }
     },
     "database_specs": [
       {
         "name": "<DB_name>"
       },
       { <similar_configuration_for_DB_2> },
       { ... },
       { <similar_configuration_for_DB_N> }
     ],
     "user_specs": [
       {
         "name": "<username>",
         "password": "<user_password>",
         "permissions": [
           {
             "database_name": "<DB_name>",
             "roles": [
               "<role_1>", "<role_2>", ..., "<role_N>"
             ]
           }
         ]
       },
       { <similar_configuration_for_user_2> },
       { ... },
       { <similar_configuration_for_user_N> }
     ],
     "host_specs": [
       {
         "zone_id": "<availability_zone>",
         "subnet_id": "<subnet_ID>",
         "assign_public_ip": <public_access_to_host:_true_or_false>,
         "type": "<host_type>",
         "shard_name": "<shard_name>",
         "hidden": <hide_host:_true_or_false>,
         "secondary_delay_secs": "<replica_lag_in_seconds>",
         "priority": "<host_priority>",
         "tags": "<host_labels>"
       },
       { <similar_configuration_for_host_2> },
       { ... },
       { <similar_configuration_for_host_N> }
     ]
   }
   

   Where:

   • folder_id: Folder ID. You can request it with the list of folders in the cloud.

   • name: Cluster name.

   • environment: Cluster environment, PRODUCTION or PRESTABLE.

   • network_id: ID of the network the cluster will be in.

   • security_group_ids: Security group IDs.

   • deletion_protection: Cluster protection from accidental deletion, true or false.

     Even with cluster deletion protection enabled, one can still delete a user or database or connect manually and delete the database contents.

   • maintenance_window: Maintenance window settings (including for disabled clusters). In maintenance_window, provide one of the two parameters:

     • anytime: Maintenance can take place at any time.

     • weekly_maintenance_window: Maintenance takes place once a week at the specified time:

       • day: Day of week, in DDD format.
       • hour: Hour, in HH format. The values range from 1 to 24 hours.

   • config_spec: Cluster settings:

     • version: MongoDB version: 5.0, 6.0, or 7.0.

       • mongod: Host type.

         • resources: Cluster resources:

           • resource_preset_id: Host class.
           • disk_size: Disk size in bytes.
           • disk_type_id: Disk type.

       • backup_window_start: Backup window settings.

         In this parameter, specify the backup start time:

         • hours: Between 0 and 23 hours.
         • minutes: Between 0 and 59 minutes.
         • seconds: Between 0 and 59 seconds.
         • nanos: Between 0 and 999999999 nanoseconds.

       • backup_retain_period_days: Backup retention in days.

       • performance_diagnostics: Statistics collection settings:

         • profiling_enabled: Enable profiler.

   • database_specs: Database settings as an array of elements, one for each DB. Each element contains the name parameter with the DB name.

     A database name may contain Latin letters, numbers, underscores, and hyphens. The name may be up to 63 characters long. Such names as config, local, admin, and mdb_internal are reserved for Managed Service for MongoDB. You cannot create DBs with these names.

   • user_specs: User settings as an array of elements, one for each user. Each element has the following structure:

     • name: Username.

     • password: User password.

     • permissions: User permission settings:

       • database_name: Name of the database the user gets access to.
       • roles: Array of user roles. Each role is provided as a separate string in the array. For a list of possible values, see Users and roles.

       For each database, add a separate element with permission settings to the permissions array.

   • host_specs: Cluster host settings as an array of elements, one for each host. Each element has the following structure:

     • zone_id: Availability zone.
     • subnet_id: Subnet ID.
     • assign_public_ip: Internet access to the host via a public IP address.
     • type: Host type in a sharded cluster, MONGOD, MONGOINFRA, MONGOS, or MONGOCFG.
     • shard_name: Shard name in a sharded cluster.
     • hidden: Hide host, true or false. If the host is hidden, only direct connections will be able to read from it (for example, to make backups from it without adding load to the cluster).
     • secondaryDelaySecs: Replica's lag behind the master in seconds. It can be useful for data recovery in case of invalid operations.
     • priority: Host priority for assignment as a master.
     • tags: Host labels.

4. Use the ClusterService.Create call and send the following request, e.g., via gRPCurl:

   grpcurl \
       -format json \
       -import-path ~/cloudapi/ \
       -import-path ~/cloudapi/third_party/googleapis/ \
       -proto ~/cloudapi/yandex/cloud/mdb/mongodb/v1/cluster_service.proto \
       -rpc-header "Authorization: Bearer $IAM_TOKEN" \
       -d @ \
       mdb.api.cloud.yandex.net:443 \
       yandex.cloud.mdb.mongodb.v1.ClusterService.Create \
       < body.json
   

5. View the server response to make sure the request was successful.

Create a Managed Service for MongoDB cluster and a network for it with the following test specifications:

• Name: mymg.

• Version: 7.0.

• Environment: PRODUCTION.

• Cloud ID: b1gq90dgh25bebiu75o.

• Folder ID: b1gia87mbaomkfvsleds.

• Network: mynet.

• Host class: s2.micro.

• Number of host blocks: 1.

• Subnet: mysubnet. Network settings:

  • Availability zone: ru-central1-a.
  • Range: 10.5.0.0/24.

• Security group: mymg-sg. The group rules allow TCP connections to the cluster from the internet via port 27018.

• Network SSD storage: network-ssd.

• Storage size: 20 GB.

• user1 user.

• Password: user1user1.

• Database: db1.

• Deletion protection: Enabled.

Configuration file for a single-host cluster:

resource "yandex_mdb_mongodb_cluster" "mymg" {
  name                = "mymg"
  environment         = "PRODUCTION"
  network_id          = yandex_vpc_network.mynet.id
  security_group_ids  = [ yandex_vpc_security_group.mymg-sg.id ]
  deletion_protection = true

  cluster_config {
    version = "7.0"
  }

  resources_mongod {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 20
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
  }
}

resource "yandex_mdb_mongodb_database" "db1" {
  cluster_id = yandex_mdb_mongodb_cluster.mymg.id
  name       = "db1"
}

resource "yandex_mdb_mongodb_user" "user1" {
  cluster_id = yandex_mdb_mongodb_cluster.mymg.id
  name       = "user1"
  password   = "user1user1"
  permission {
    database_name = "db1"
  }
  depends_on = [
    yandex_mdb_mongodb_database.db1
  ]
}

resource "yandex_vpc_network" "mynet" {
  name = "mynet"
}

resource "yandex_vpc_security_group" "mymg-sg" {
  name       = "mymg-sg"
  network_id = yandex_vpc_network.mynet.id

  ingress {
    description    = "MongoDB"
    port           = 27018
    protocol       = "TCP"
    v4_cidr_blocks = [ "0.0.0.0/0" ]
  }
}

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.mynet.id
  v4_cidr_blocks = ["10.5.0.0/24"]
}

The configuration file for a cluster with standard sharding is as follows:

resource "yandex_mdb_mongodb_cluster" "mymg" {
  name                = "mymg"
  environment         = "PRODUCTION"
  network_id          = yandex_vpc_network.mynet.id
  security_group_ids  = [ yandex_vpc_security_group.mymg-sg.id ]
  deletion_protection = true

  cluster_config {
    version = "7.0"
  }

  resources_mongod {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 10
  }

  resources_mongoinfra {
    resource_preset_id = "c3-c2-m4"
    disk_type_id       = "network-ssd"
    disk_size          = 10
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongod"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongoinfra"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongoinfra"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongoinfra"
  }

resource "yandex_mdb_mongodb_database" "db1" {
  cluster_id = yandex_mdb_mongodb_cluster.mymg.id
  name       = "db1"
}

resource "yandex_mdb_mongodb_user" "user1" {
  cluster_id = yandex_mdb_mongodb_cluster.mymg.id
  name       = "user1"
  password   = "user1user1"
  permission {
    database_name = "db1"
  }
  depends_on = [
    yandex_mdb_mongodb_database.db1
  ]
}

resource "yandex_vpc_network" "mynet" {
  name = "mynet"
}

resource "yandex_vpc_security_group" "mymg-sg" {
  name       = "mymg-sg"
  network_id = yandex_vpc_network.mynet.id

  ingress {
    description    = "MongoDB"
    port           = 27018
    protocol       = "TCP"
    v4_cidr_blocks = [ "0.0.0.0/0" ]
  }
}

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.mynet.id
  v4_cidr_blocks = ["10.5.0.0/24"]
}

The configuration file for a cluster with advanced sharding is as follows:

resource "yandex_mdb_mongodb_cluster" "mymg" {
  name                = "mymg"
  environment         = "PRODUCTION"
  network_id          = yandex_vpc_network.mynet.id
  security_group_ids  = [ yandex_vpc_security_group.mymg-sg.id ]
  deletion_protection = true

  cluster_config {
    version = "7.0"
  }

  resources_mongod {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 10
  }

  resources_mongos {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 10
  }

  resources_mongocfg {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 10
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongod"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongos"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongos"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongocfg"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongocfg"
  }

  host {
    zone_id   = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.mysubnet.id
    type      = "mongocfg"
  }
}

resource "yandex_mdb_mongodb_database" "db1" {
  cluster_id = yandex_mdb_mongodb_cluster.mymg.id
  name       = "db1"
}

resource "yandex_mdb_mongodb_user" "user1" {
  cluster_id = yandex_mdb_mongodb_cluster.mymg.id
  name       = "user1"
  password   = "user1user1"
  permission {
    database_name = "db1"
  }
  depends_on = [
    yandex_mdb_mongodb_database.db1
  ]
}

resource "yandex_vpc_network" "mynet" {
  name = "mynet"
}

resource "yandex_vpc_security_group" "mymg-sg" {
  name       = "mymg-sg"
  network_id = yandex_vpc_network.mynet.id

  ingress {
    description    = "MongoDB"
    port           = 27018
    protocol       = "TCP"
    v4_cidr_blocks = [ "0.0.0.0/0" ]
  }
}

resource "yandex_vpc_subnet" "mysubnet" {
  name           = "mysubnet"
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.mynet.id
  v4_cidr_blocks = ["10.5.0.0/24"]
}