Добавить правило-исключение WAF

Terraform позволяет быстро создать облачную инфраструктуру в Yandex Cloud и управлять ею с помощью файлов конфигураций. В файлах конфигураций хранится описание инфраструктуры на языке HCL (HashiCorp Configuration Language). При изменении файлов конфигураций Terraform автоматически определяет, какая часть вашей конфигурации уже развернута, что следует добавить или удалить.

Terraform распространяется под лицензией Business Source License, а провайдер Yandex Cloud для Terraform — под лицензией MPL-2.0.

Подробная информация о ресурсах провайдера в документации на сайте Terraform или в зеркале.

Если у вас еще нет Terraform, установите его и настройте провайдер Yandex Cloud.

Чтобы управлять инфраструктурой с помощью Terraform от имени сервисного аккаунта или пользовательских аккаунтов: аккаунта на Яндексе, федеративного аккаунта и локального пользователя, аутентифицируйтесь соответствующим способом.

1. Откройте файл конфигурации Terraform и измените фрагмент с описанием профиля WAF yandex_sws_waf_profile: добавьте блок exclusion_rule с правилом-исключением WAF.

   # Профиль WAF
   resource "yandex_sws_waf_profile" "default" {
     name = "waf-profile-default"
   
     ...
   
     # Правило-исключение
     exclusion_rule {
       name = "<имя_правила-исключения>"
       condition {
         source_ip {
           ip_ranges_match {
             ip_ranges = [
               "<диапазон_IP-адресов_1>",
               "<диапазон_IP-адресов_2>",
               ...
               "<диапазон_IP-адресов_n>"
             ]
           }
           ip_ranges_not_match {
             ip_ranges = [
               "<диапазон_IP-адресов_3>",
               "<диапазон_IP-адресов_4>",
               ...
               "<диапазон_IP-адресов_y>"
             ]
           }
         }
       }
   
       exclude_rules {
         exclude_all = <true_или_false>
         rule_ids    = [
           "идентификатор_правила_1",
           "идентификатор_правила_2",
           ...
           "идентификатор_правила_n"
         ]
       }
     }
   }
   
   Пример настройки правил-исключений профиля WAF в конфигурации Terraform

   # Объявление локальных переменных
   locals {
     # В базовом наборе будут активны правила этого уровня паранойи и ниже
     waf_paranoia_level = 1
   
     # Идентификация набора правил OWASP Core Ruleset
     ruleset_name    = "OWASP Core Ruleset"
     ruleset_version = "4.0.0"
     ruleset_id      = "OWASP_CRS_4_0_0"
     ruleset_type    = "CORE"
   }
   
   # Источник данных OWASP Core Rule Set
   data "yandex_sws_waf_rule_set_descriptor" "source" {
     name    = local.ruleset_name
     version = local.ruleset_version
   }
   
   # Профиль WAF
   resource "yandex_sws_waf_profile" "default" {
     name = "configure-set-rules"
   
     # Базовый набор правил
     rule_set {
       action     = "CAPTCHA"
       is_enabled = true
       priority   = 1
       core_rule_set {
         inbound_anomaly_score = 2
         paranoia_level        = local.waf_paranoia_level
         rule_set {
           name    = local.ruleset_name
           version = local.ruleset_version
           id      = local.ruleset_id
           type    = local.ruleset_type
         }
       }
     }
   
     # Правило-исключение
     exclusion_rule {
       name = "test-exclusion-1"
   
       condition {
         source_ip {
           ip_ranges_match {
             ip_ranges = [
               "192.0.2.0/24",
               "198.51.100.0/24"
             ]
           }
           ip_ranges_not_match {
             ip_ranges = [
               "203.0.113.10/32",
               "203.0.113.0/24"
             ]
           }
         }
       }
   
       exclude_rules {
         exclude_all = false
         rule_ids = [
           "owasp-crs-v4.8.0-id942330-attack-sqli",
           "owasp-crs-v4.8.0-id920202-protocol-enforcement"
         ]
       }
   
     }
   }
   

   Где:

   • exclusion_rule — правило-исключение:

     • name — имя правила-исключения.

     • condition — условия, при которых будет срабатывать правило-исключение. В приведенном примере применяется условие по IP-адресу источника трафика.

       В блоке condition вы можете использовать одновременно несколько разных типов условий.

     • exclude_rules — параметры правила-исключения:

       • exclude_all — исключение будет срабатывать для всех правил. Возможные значения: false или true.
       • rule_ids — список идентификаторов правил из базового набора, для которых будет срабатывать исключение. Чтобы указать отдельные правила, для параметра exclude_all установите значение false.

   Подробнее о параметрах ресурса yandex_sws_waf_profile в документации провайдера.

2. Примените изменения:

   1. В терминале перейдите в директорию с конфигурационным файлом.

   2. Проверьте корректность конфигурации с помощью команды:

      terraform validate
      

      Если конфигурация является корректной, появится сообщение:

      Success! The configuration is valid.
      

   3. Выполните команду:

      terraform plan
      

      В терминале будет выведен список ресурсов с параметрами. На этом этапе изменения не будут внесены. Если в конфигурации есть ошибки, Terraform на них укажет.

   4. Примените изменения конфигурации:

      terraform apply
      

   5. Подтвердите изменения: введите в терминале слово yes и нажмите Enter.

Вы можете проверить изменение ресурсов в консоли управления.

Воспользуйтесь методом REST API update для ресурса WafProfile или вызовом gRPC API WafProfile/Update.