Создание ВМ и группы ВМ с Container Optimized Image с помощью Terraform

Чтобы с помощью Terraform создать конфигурации и запустить виртуальную машину или группу виртуальных машин на базе образа Container Optimized Image, выполните следующие действия.

Перед началом работыПеред началом работы

Если у вас еще нет Terraform, установите его и настройте провайдер Yandex Cloud.

Чтобы управлять инфраструктурой с помощью Terraform от имени сервисного аккаунта или пользовательских аккаунтов: аккаунта на Яндексе, федеративного аккаунта и локального пользователя, аутентифицируйтесь соответствующим способом.

В сценарии используется конфигурационный файл с названием example.tf, который находится в директории ~/cloud-terraform.

Создание и запуск ВМ с образом Container Optimized ImageСоздание и запуск ВМ с образом Container Optimized Image

В этом разделе вы создадите:

• облачную сеть sample-network;
• подсеть sample-network-subnet;
• группу безопасности sample-sg;
• виртуальную машину sample-coi-vm.

Создайте файлы конфигурации ВМСоздайте файлы конфигурации ВМ

1. Опишите сетевые ресурсы, которые необходимы для работы виртуальной машины, и добавьте эти описания в конфигурационный файл example.tf:

   terraform {
     required_providers {
       yandex = {
         source = "yandex-cloud/yandex"
       }
     }
     required_version = ">= 0.13"
   }
   
   provider "yandex" {
     cloud_id    = local.cloud_id
     folder_id   = local.folder_id
   }
   
   locals {
     cloud_id    = "<идентификатор_облака>"
     folder_id   = "<идентификатор_каталога>"
     zone        = "<зона_доступности>"
     cidr        = "<CIDR_подсети>"
   }
   
   # Создание сети
   
   resource "yandex_vpc_network" "coi-instance-network" {
     name = "sample-network"
   }
   
   # Создание подсети
   
   resource "yandex_vpc_subnet" "coi-instance-subnet-d" {
     name           = "sample-network-subnet"
     zone           = local.zone
     network_id     = yandex_vpc_network.coi-instance-network.id
     v4_cidr_blocks = [local.cidr]
   }
   
   # Создание группы безопасности
   
   resource "yandex_vpc_security_group" "coi-instance-sg" {
     name        = "sample-sg"
     network_id  = yandex_vpc_network.coi-instance-network.id
   
     ingress {
       protocol       = "TCP"
       description    = "http"
       v4_cidr_blocks = ["0.0.0.0/0"]
       port           = 80
     }
   
     ingress {
       protocol       = "TCP"
       description    = "https"
       v4_cidr_blocks = ["0.0.0.0/0"]
       port           = 443
     }
   
     ingress {
       protocol       = "TCP"
       description    = "ssh"
       v4_cidr_blocks = ["0.0.0.0/0"]
       port           = 22
     }
   
     egress {
       protocol       = "ANY"
       description    = "any"
       v4_cidr_blocks = ["0.0.0.0/0"]
       from_port      = 0
       to_port        = 65535
     }
   }
   

   Где locals — локальные переменные конфигурации, которые необходимо задать для создания инфраструктуры:

   • cloud_id — идентификатор облака, в котором вы будете создавать инфраструктуру.
   • folder_id — идентификатор каталога, в котором вы будете создавать инфраструктуру.
   • zone — зона доступности, в которой вы будете создавать инфраструктуру. Например: kz1-a.
   • cidr — CIDR подсети, в которой вы будете создавать виртуальную машину. Например: 192.168.1.0/24.

2. Используйте образ Container Optimized Image из семейства образов Yandex Cloud. Для этого в конфигурационный файл example.tf добавьте строки:

   data "yandex_compute_image" "container-optimized-image" {
     family = "container-optimized-image"
   }
   

3. Опишите виртуальную машину, добавив в конфигурационный файл example.tf строки:

   resource "yandex_compute_instance" "instance-based-on-coi" {
     name        = "sample-coi-vm"
     platform_id = "standard-v3"
     zone        = local.zone
   
     boot_disk {
       initialize_params {
         image_id = data.yandex_compute_image.container-optimized-image.id
       }
     }
     network_interface {
       subnet_id = yandex_vpc_subnet.coi-instance-subnet-d.id
       nat = true
       security_group_ids = [yandex_vpc_security_group.coi-instance-sg.id]
     }
     resources {
       cores = 2
       memory = 2
     }
     metadata = {
       docker-container-declaration = file("${path.module}/declaration.yaml")
       user-data = file("${path.module}/cloud_config.yaml")
     }
   }
   

   Если вы используете спецификацию Docker Compose, то ключ docker-container-declaration в metadata необходимо заменить на ключ docker-compose:

   metadata = {
     docker-compose = file("${path.module}/docker-compose.yaml")
     user-data = file("${path.module}/cloud_config.yaml")
   }
   

4. В директории ~/cloud-terraform создайте файл спецификации облака cloud_config.yaml. В нем опишите спецификацию:

   #cloud-config
   ssh_pwauth: no
   users:
     - name: yc-user
       sudo: ALL=(ALL) NOPASSWD:ALL
       shell: /bin/bash
       ssh_authorized_keys:
         - "<публичный_SSH-ключ>"
   

   Где ssh_authorized_keys — значение публичного SSH-ключа.

5. В директории ~/cloud-terraform создайте файл спецификации Container Optimized Image declaration.yaml. В нем опишите спецификацию:

   spec:
     containers:
     - image: cr.yandexcloud.kz/yc/demo/coi:v1
       securityContext:
         privileged: false
       stdin: false
       tty: false
   

6. В директории ~/cloud-terraform создайте файл output.tf, чтобы отобразить публичный IP-адрес ВМ. В него добавьте следующий код:

   output "external_ip" {
     value = yandex_compute_instance.instance-based-on-coi.network_interface.0.nat_ip_address
   }
   

Создайте ВМ с Container Optimized ImageСоздайте ВМ с Container Optimized Image

Запустите ВМ с Container Optimized Image, используя конфигурацию Terraform.

Создание и запуск группы ВМ с образом Container Optimized ImageСоздание и запуск группы ВМ с образом Container Optimized Image

В этом разделе вы создадите:

• облачную сеть sample-network;
• подсети sample-network-subnet1 и sample-network-subnet2;
• группу безопасности sample-sg;
• сервисный аккаунт instance-group-sa с назначенными ролями compute.admin и vpc.publicAdmin;
• группу виртуальных машин ig-with-coi.

Создайте файлы конфигурации группы ВМСоздайте файлы конфигурации группы ВМ

1. В директории ~/cloud-terraform сохраните конфигурационный файл с именем example.tf:

   terraform {
     required_providers {
       yandex = {
         source = "yandex-cloud/yandex"
       }
     }
     required_version = ">= 0.13"
   }
   
   provider "yandex" {
     cloud_id    = local.cloud_id
     folder_id   = local.folder_id
   }
   
   locals {
     cloud_id    = "<идентификатор_облака>"
     folder_id   = "<идентификатор_каталога>"
     zone1       = "<зона_доступности_1>"
     zone2       = "<зона_доступности_2>"
     cidr1       = "<CIDR_подсети_1>"
     cidr2       = "<CIDR_подсети_2>"
   }
   
   # Создание сети
   
   resource "yandex_vpc_network" "coi-instance-network" {
     name = "sample-network"
   }
   
   # Создание подсетей
   
   resource "yandex_vpc_subnet" "coi-instance-subnet1" {
     name           = "sample-network-subnet1"
     zone           = local.zone1
     network_id     = yandex_vpc_network.coi-instance-network.id
     v4_cidr_blocks = [local.cidr1]
   }
   
   resource "yandex_vpc_subnet" "coi-instance-subnet2" {
     name           = "sample-network-subnet2"
     zone           = local.zone2
     network_id     = yandex_vpc_network.coi-instance-network.id
     v4_cidr_blocks = [local.cidr2]
   }
   
   # Создание группы безопасности
   
   resource "yandex_vpc_security_group" "coi-instance-sg" {
     name        = "sample-sg"
     network_id  = yandex_vpc_network.coi-instance-network.id
   
     ingress {
       protocol       = "TCP"
       description    = "http"
       v4_cidr_blocks = ["0.0.0.0/0"]
       port           = 80
     }
   
     ingress {
       protocol       = "TCP"
       description    = "https"
       v4_cidr_blocks = ["0.0.0.0/0"]
       port           = 443
     }
   
     ingress {
       protocol       = "TCP"
       description    = "ssh"
       v4_cidr_blocks = ["0.0.0.0/0"]
       port           = 22
     }
   
     egress {
       protocol       = "ANY"
       description    = "any"
       v4_cidr_blocks = ["0.0.0.0/0"]
       from_port      = 0
       to_port        = 65535
     }
   }
   
   # Создание сервисного аккаунта
   
   resource "yandex_iam_service_account" "ig-sa" {
     name = "instance-group-sa"
   }
   
   # Назначение сервисному аккаунту ролей compute.admin и vpc.publicAdmin
   
   resource "yandex_resourcemanager_folder_iam_member" "compute-admin" {
     folder_id = local.folder_id
     role      = "compute.admin"
     member    = "serviceAccount:${yandex_iam_service_account.ig-sa.id}"
   }
   
   resource "yandex_resourcemanager_folder_iam_member" "vpc-public-admin" {
     folder_id = local.folder_id
     role      = "vpc.publicAdmin"
     member    = "serviceAccount:${yandex_iam_service_account.ig-sa.id}"
   }
   
   # Получение информации об образе Container Optimized Image
   
   data "yandex_compute_image" "container-optimized-image" {
     family = "container-optimized-image"
   }
   
   # Создание группы виртуальных машин
   
   resource "yandex_compute_instance_group" "ig-with-coi" {
   
     depends_on = [
       yandex_resourcemanager_folder_iam_member.compute-admin
     ]
   
     name = "ig-with-coi"
     folder_id = local.folder_id
     service_account_id = yandex_iam_service_account.ig-sa.id
     instance_template {
       platform_id = "standard-v3"
       resources {
         memory = 2
         cores  = 2
       }
       boot_disk {
         mode = "READ_WRITE"
         initialize_params {
           image_id = data.yandex_compute_image.container-optimized-image.id
         }
       }
       network_interface {
         network_id = yandex_vpc_network.coi-instance-network.id
         subnet_ids = [yandex_vpc_subnet.coi-instance-subnet1.id,yandex_vpc_subnet.coi-instance-subnet2.id]
         security_group_ids = [yandex_vpc_security_group.coi-instance-sg.id]
         nat = true
       }
       metadata = {
         docker-container-declaration = file("${path.module}/declaration.yaml")
         user-data = file("${path.module}/cloud_config.yaml")
       }
     }
     scale_policy {
       fixed_scale {
         size = 2
       }
     }
     allocation_policy {
       zones = [local.zone1,local.zone2]
     }
     deploy_policy {
       max_unavailable = 2
       max_creating = 2
       max_expansion = 2
       max_deleting = 2
     }
   }
   

   Где locals — локальные переменные конфигурации, которые необходимо задать для создания инфраструктуры:

   • cloud_id — идентификатор облака, в котором вы будете создавать инфраструктуру.
   • folder_id — идентификатор каталога, в котором вы будете создавать инфраструктуру.
   • zone1, zone2 — зоны доступности, в которых вы будете создавать подсети и в которых будут распределяться виртуальные машины группы. Например: kz1-a и kz1-b.
   • cidr1, cidr2 — CIDR подсетей, в которых будут располагаться виртуальные машины группы. Например: 192.168.1.0/24 и 172.16.1.0/24.

2. Используйте файлы cloud_config.yaml и declaration.yaml из раздела Создайте файлы конфигурации ВМ.

3. В директории ~/cloud-terraform создайте файл output.tf, чтобы отобразить публичные IP-адреса каждой ВМ из группы:

   output "external_ip" {
     value = [yandex_compute_instance_group.ig-with-coi.instances[*].network_interface[0].nat_ip_address]
   }
   

Создайте группу ВМ с Container Optimized ImageСоздайте группу ВМ с Container Optimized Image

Запустите группу ВМ с Container Optimized Image, используя конфигурацию Terraform.