Configuring WAF rule sets

With Terraform, you can quickly create a cloud infrastructure in Yandex Cloud and manage it using configuration files. These files store the infrastructure description written in HashiCorp Configuration Language (HCL). If you change the configuration files, Terraform automatically detects which part of your configuration is already deployed, and what should be added or removed.

Terraform is distributed under the Business Source License. The Yandex Cloud provider for Terraform is distributed under the MPL-2.0 license.

For more information about the provider resources, see the guides on the Terraform website or its mirror.

If you do not have Terraform yet, install it and configure the Yandex Cloud provider.

To manage infrastructure using Terraform under a service account or user accounts (a Yandex account, a federated account, or a local user), authenticate using the appropriate method.

You can dynamically activate all the basic set rules if their paranoia level is not higher than the custom variable. For dynamic rules, you can edit the settings manually. For example, you can turn a rule into a blocking one and enable a rule with the paranoia level higher than the one defined in the variable.

1. Open the Terraform configuration file and edit the WAF profile description fragment yandex_sws_waf_profile: add either the rule section with a security rule or the dynamic "rule" section with dynamically configured rules.

   # Declaring local variables
   locals {
     # In the basic set, rules of this paranoia level and below will be enabled
     waf_paranoia_level = <paranoia_level>
   }
   
   # Data source: rule set
   data "yandex_sws_waf_rule_set_descriptor" "source" {
     name    = "<set_name>"
   }
   
   # WAF profile
   resource "yandex_sws_waf_profile" "default" {
     name = "default"
   
     ...
   
     # Turning the rule into a blocking one: the request will be blocked regardless of the anomaly threshold
     rule {
       rule_id     = "<rule_1_ID>"
       is_enabled  = true
       is_blocking = true
     }
   
     # Enabling the rule with paranoia level 4
     rule {
       rule_id     = "<rule_2_ID>"
       is_enabled  = true
       is_blocking = false
     }
   
     # Enabling rules from the basic set if their paranoia level is not higher than the value defined in the waf_paranoia_level variable
     dynamic "rule" {
       for_each = [
         for rule in data.yandex_sws_waf_rule_set_descriptor.source.rules : rule
         if rule.paranoia_level <= local.waf_paranoia_level
       ]
       content {
         rule_id     = rule.value.id
         is_enabled  = true
         is_blocking = false
       }
     }
   }
   
   Example of configuring WAF profile rule sets in your Terraform configuration

   # Declaring local variables
   locals {
     # In the basic set, rules of this paranoia level and below will be enabled
     waf_paranoia_level = 1
   
     # OWASP Core Ruleset identification
     ruleset_name    = "OWASP Core Ruleset"
     ruleset_version = "4.0.0"
     ruleset_id      = "OWASP_CRS_4_0_0"
     ruleset_type    = "CORE"
   }
   
   # OWASP Core Rule Set data source
   data "yandex_sws_waf_rule_set_descriptor" "source" {
     name    = local.ruleset_name
     version = local.ruleset_version
   }
   
   # WAF profile
   resource "yandex_sws_waf_profile" "default" {
     name = "default"
   
     # Basic rule set
     rule_set {
       action     = "DENY"
       is_enabled = true
       priority   = 1
       core_rule_set {
         inbound_anomaly_score = 2
         paranoia_level        = local.waf_paranoia_level
         rule_set {
           name    = local.ruleset_name
           version = local.ruleset_version
           id      = local.ruleset_id
           type    = local.ruleset_type
         }
       }
     }
   
     # Turning the rule into a blocking one: the request will be blocked regardless of the anomaly threshold
     rule {
       rule_id     = "owasp-crs-v4.0.0-id942330-attack-sqli"
       is_enabled  = true
       is_blocking = true
     }
   
     # Enabling the rule with paranoia level 4
     rule {
       rule_id     = "owasp-crs-v4.0.0-id920202-protocol-enforcement"
       is_enabled  = true
       is_blocking = false
     }
   
     # Enabling rules from the basic set if their paranoia level is not higher than the value defined in the waf_paranoia_level variable
     dynamic "rule" {
       for_each = [
         for rule in data.yandex_sws_waf_rule_set_descriptor.source.rules : rule
         if rule.paranoia_level <= local.waf_paranoia_level
       ]
       content {
         rule_id     = rule.value.id
         is_enabled  = true
         is_blocking = false
       }
     }
   }
   

   Where:

   • rule: Security rule description:

     • rule_id: Rule ID.
     • is_enabled: Flag to enable or disable a rule.
     • is_blocking: Blocking rule flag. If true, the rule becomes the blocking one.

   • dynamic "rule": Dynamic activation of the basic set rules if their paranoia level is not higher than the waf_paranoia_level variable. For dynamic rules, you can edit the settings manually. For example, you can turn a rule into a blocking one or enable a rule with the paranoia level higher than the one defined in the variable.

     • rule_id: Rule ID.
     • is_enabled: Flag to enable or disable a rule.
     • is_blocking: Blocking rule flag. If true, the rule becomes the blocking one.

   For more on the properties of the yandex_sws_waf_profile resource, see this provider guide.

2. Apply the changes:

   1. In the terminal, navigate to the configuration file directory.

   2. Make sure the configuration is correct using this command:

      terraform validate
      

      If the configuration is valid, you will get this message:

      Success! The configuration is valid.
      

   3. Run this command:

      terraform plan
      

      You will see a list of resources and their properties. No changes will be made at this step. Terraform will show any errors in the configuration.

   4. Apply the configuration changes:

      terraform apply
      

   5. Type yes and press Enter to confirm the changes.

You can check the update in the management console.

Use the update REST API method for the WafProfile resource or the WafProfile/Update gRPC API call.