Creating a new message queue

1. Install and configure the AWS CLI.

2. Run the following command in the terminal:

   aws sqs create-queue \
     --queue-name <queue_name> \
     --endpoint <endpoint>
   

   Where:

   • --queue-name: Name of the new queue, e.g., sample-queue.
   • --endpoint: Endpoint in the https://message-queue.api.cloud.yandex.net/ value.

   Result:

   {
       "QueueUrl": "https://message-queue.api.cloud.yandex.net/aoeaql9r10cd********/000000000000********/sample-queue"
   }
   

With Terraform, you can quickly create a cloud infrastructure in Yandex Cloud and manage it using configuration files. These files store the infrastructure description written in HashiCorp Configuration Language (HCL). If you change the configuration files, Terraform automatically detects which part of your configuration is already deployed, and what should be added or removed.

Terraform is distributed under the Business Source License. The Yandex Cloud provider for Terraform is distributed under the MPL-2.0 license.

For more information about the provider resources, see the documentation on the Terraform website or mirror website.

If you do not have Terraform yet, install it and configure its Yandex Cloud provider.

To create a message queue:

1. In the configuration file, describe the parameters of the queue to create:

   Sample configuration file for a standard queue:

   provider "yandex" {
      token     = "<OAuth or service account static key>"
      folder_id = "<folder ID>"
      zone      = "ru-central1-a"
   }
   
   resource "yandex_message_queue" "example_queue" {
     name                        = "mq-terraform-example"
     visibility_timeout_seconds  = 600
     receive_wait_time_seconds   = 20
     message_retention_seconds   = 1209600
     access_key                  = "<ID_of_the_static_access_key>"
     secret_key                  = "<secret_part_of_the_static_access_key>"
   }
   

   Sample configuration file for a FIFO queue:

   provider "yandex" {
       token     = "<OAuth_or_service_account_static_key>"
       folder_id = "<folder_ID>"
       zone      = "ru-central1-a"
     }
   
   resource "yandex_message_queue" "example-fifo-queue" {
     name                        = "mq-terraform-example.fifo"
     visibility_timeout_seconds  = 600
     receive_wait_time_seconds   = 20
     message_retention_seconds   = 1209600
     fifo_queue                  = true
     access_key                  = "<ID_of_the_static_access_key>"
     secret_key                  = "<secret_part_of_the_static_access_key>"
   }
   

   Sample configuration file for a queue with a redrive policy for moving undelivered messages to a DLQ named mq_terraform_deadletter_example:

   provider "yandex" {
      token     = "<OAuth_or_service_account_static_key>"
      folder_id = "<folder_ID>"
      zone      = "ru-central1-a"
   }
   
   resource "yandex_message_queue" "example_fifo_queue" {
     name                        = "mq-terraform-example"
     visibility_timeout_seconds  = 600
     receive_wait_time_seconds   = 20
     message_retention_seconds   = 1209600
     redrive_policy              = jsonencode({
       deadLetterTargetArn = yandex_message_queue.example_deadletter_queue.arn
       maxReceiveCount     = 3
     })
     access_key                  = "<ID_of_the_static_access_key>"
     secret_key                  = "<secret_part_of_the_static_access_key>"
   }
   
   resource "yandex_message_queue" "example_deadletter_queue" {
     name                        = "mq_terraform_deadletter_example"
     access_key                  = "<ID_of_the_static_access_key>"
     secret_key                  = "<secret_part_of_the_static_access_key>"
   }
   

   Where:

   • name: Queue name.

   • visibility_timeout_seconds: Visibility timeout.

   • receive_wait_time_seconds: Waiting time for messages to enter the queue if Long Polling is used. The valid values are from 0 to 20 seconds. The default value is 0 seconds.

   • message_retention_seconds: Time, in seconds, to retain a message in the queue.

   • redrive_policy: Redirect policy for moving messages to a dead-letter queue.

     • deadLetterTargetArn: ARN of the DLQ that messages are moved to.
     • maxReceiveCount: Number of attempts to read a message from the queue before redriving it to the DLQ.

   • fifo_queue: Indicates that a FIFO queue is created.

   • content_based_deduplication: Enables content-based deduplication in FIFO queues.

   • access_key: ID of the service account static access key for the queue. If it is not specified in the queue configuration, the ID from the provider configuration is used.

   • secret_key: Secret part of the static access key. If no secret key is set in the queue configuration, the key from the provider configuration is used.

   For more information about resources you can create with Terraform, see the provider documentation.

2. Make sure the configuration files are correct.

   1. In the command line, go to the directory where you created the configuration file.

   2. Run a check using this command:

      terraform plan
      

   If the configuration is described correctly, the terminal will display a list of created resources and their parameters. If the configuration contains any errors, Terraform will point them out.

3. Deploy cloud resources.

   1. If the configuration does not contain any errors, run this command:

      terraform apply
      

   2. Confirm that you want to create the resources.

   All the resources you need will then be created in the specified folder. You can check the new resources and their configuration using the management console. To delete the created resources, run the terraform destroy command.