Getting started with API Gateway

With Terraform, you can quickly create a cloud infrastructure in Yandex Cloud and manage it using configuration files. These files store the infrastructure description written in HashiCorp Configuration Language (HCL). If you change the configuration files, Terraform automatically detects which part of your configuration is already deployed, and what should be added or removed.

Terraform is distributed under the Business Source License. The Yandex Cloud provider for Terraform is distributed under the MPL-2.0 license.

For more information about the provider resources, see the documentation on the Terraform website or mirror website.

If you don't have Terraform, install it and configure the Yandex Cloud provider.

To create an API gateway:

1. Describe the parameters of the yandex_api_gateway resource in the configuration file:

   • name: API gateway name. The name format is as follows:

     • The name must be from 3 to 63 characters long.
     • It may contain lowercase Latin letters, numbers, and hyphens.
     • The first character must be a letter and the last character cannot be a hyphen.

   • description: API gateway description.

   • labels: Labels for the API gateway. Specify a key-value pair.

   • spec: API gateway specification.

   Here is an example of the configuration file structure:

   resource "yandex_api_gateway" "test-api-gateway" {
     name        = "<API_gateway_name>"
     description = "<API_gateway_description>"
     labels      = {
       label       = "label"
       empty-label = ""
     }
     spec = <<-EOT
       openapi: "3.0.0"
       info:
         version: 1.0.0
         title: Test API
       paths:
         /hello:
           get:
             summary: Say hello
             operationId: hello
             parameters:
               - name: user
                 in: query
                 description: User name to appear in greetings
                 required: false
                 schema:
                   type: string
                   default: 'world'
             responses:
               '200':
                 description: Greeting
                 content:
                   'text/plain':
                     schema:
                       type: "string"
             x-yc-apigateway-integration:
               type: dummy
               http_code: 200
               http_headers:
                 'Content-Type': "text/plain"
               content:
                 'text/plain': "Hello, {user}!\n"
     EOT
   }
   

   For more information about resource parameters in Terraform, see the provider documentation.

2. Make sure the configuration files are correct.

   1. In the command line, go to the directory where you created the configuration file.

   2. Run a check using this command:

      terraform plan
      

   If the configuration is described correctly, the terminal will display a list of created resources and their parameters. If the configuration contains any errors, Terraform will point them out.

3. Deploy cloud resources.

   1. If the configuration does not contain any errors, run this command:

      terraform apply
      

   2. Confirm creating the resources: type yes in the terminal and press Enter.

      All the resources you need will then be created in the specified folder. You can check the new resources and their configuration using the management console or these CLI commands:

      yc serverless api-gateway get <API_gateway_name>
      

To create a function:

1. Prepare a ZIP archive with the function code:

   1. Save the following code to a file named index.js:

      module.exports.handler = async (event) => {
        return {
          "statusCode": 200,
          "headers": {"content-type": "application/json"},
          "body": "[0, 1, 2]"
        };
      };
      

   2. Add the index.js file into the hello-js.zip archive.

2. Describe the parameters of the yandex_function resource in the configuration file:

   resource "yandex_function" "test-function" {
     name               = "test-function"
     description        = "Test function"
     user_hash          = "first-function"
     runtime            = "nodejs18"
     entrypoint         = "index.handler"
     memory             = "128"
     execution_timeout  = "10"
     service_account_id = "<service_account_ID>"
     tags               = ["my_tag"]
     content {
       zip_filename = "<path_to_ZIP_archive>"
     }
   }
   

   Where:

   • name: Function name.
   • description: Text description of the function.
   • user_hash: Any string to identify the function version. When the function changes, update this string, too. The function will update when this string is updated.
   • runtime: Function runtime environment.
   • entrypoint: Function name in the source code that will serve as an entry point to applications.
   • memory: Amount of memory allocated for the function, in MB.
   • execution_timeout: Function execution timeout.
   • service_account_id: ID of the service account to call the function under.
   • tags: Function tags.
   • content: Function source code.
   • content.0.zip_filename: Path to the ZIP archive containing the function source code.

   For more information about the yandex_function resource parameters, see the provider documentation.

3. Make sure the configuration files are correct.

   1. In the command line, go to the folder where you created the configuration file.

   2. Run a check using this command:

      terraform plan
      

   If the configuration is described correctly, the terminal will display a list of created resources and their parameters. If the configuration contains any errors, Terraform will point them out.

4. Deploy cloud resources.

   1. If the configuration does not contain any errors, run this command:

      terraform apply
      

   2. Confirm creating the resources: type yes in the terminal and press Enter.

      All the resources you need will then be created in the specified folder. You can check the new resources and their settings using the management console or these CLI commands:

      yc serverless function list
      

To add function information to the API gateway specification:

1. Open the Terraform configuration file and add the /numbers method which uses the x-yc-apigateway-integration extension of the cloud_functions type to invoke a function by ID. In the spec section, update the API gateway specification by providing the following parameters:

   • function_id: Function ID.
   • service_account_id: ID of the service account with the permissions to invoke the function.

   Extended API gateway specification:

   ...
   
     spec = <<-EOT
       openapi: "3.0.0"
       info:
         version: 1.0.0
         title: Test API
       paths:
         /hello:
           get:
             summary: Say hello
             operationId: hello
             parameters:
               - name: user
                 in: query
                 description: User name to appear in greetings.
                 required: false
                 schema:
                   type: string
                   default: 'world'
             responses:
               '200':
                 description: Greeting
                 content:
                   'text/plain':
                     schema:
                       type: "string"
             x-yc-apigateway-integration:
               type: dummy
               http_code: 200
               http_headers:
                 'Content-Type': "text/plain"
               content:
                 'text/plain': "Hello again, {user}!\n"
         /numbers:
           get:
             summary: List some numbers
             operationId: listNumbers
             responses:
               '200':
                 description: Another example.
                 content:
                   'application/json':
                     schema:
                       type: "array"
                       items:
                         type: "integer"
             x-yc-apigateway-integration:
               type: cloud_functions
               function_id: <function_ID>
               service_account_id: <service_account_ID>
     EOT
   }
   

   For more information about resource parameters in Terraform, see the provider documentation.

2. Make sure the configuration files are correct.

   1. In the command line, go to the folder where you created the configuration file.

   2. Run a check using this command:

      terraform plan
      

   If the configuration is described correctly, the terminal will display a list of created resources and their parameters. If the configuration contains any errors, Terraform will point them out.

3. Deploy cloud resources.

   1. If the configuration does not contain any errors, run this command:

      terraform apply
      

   2. Confirm creating the resources: type yes in the terminal and press Enter.

      All the resources you need will then be created in the specified folder. You can check the new resources and their settings using the management console or these CLI commands:

      yc serverless api-gateway get <API_gateway_name>